Power Programmierung 2/Power-Programmierung CD 2 (Tewi)(1994).iso/gnu/gnulib/ghostscr/vms_cc.mak

Text File | 1990-12-31 | 5.1 KB | 227 lines

$ !    Copyright (C) 1989, 1990 Aladdin Enterprises.  All rights reserved.
$ !    Distributed by Free Software Foundation, Inc.
$ !
$ ! This file is part of Ghostscript.
$ !
$ ! Ghostscript is distributed in the hope that it will be useful, but
$ ! WITHOUT ANY WARRANTY.  No author or distributor accepts responsibility
$ ! to anyone for the consequences of using it or for whether it serves any
$ ! particular purpose or works at all, unless he says so in writing.  Refer
$ ! to the Ghostscript General Public License for full details.
$ !
$ ! Everyone is granted permission to copy, modify and redistribute
$ ! Ghostscript, but only under the conditions described in the Ghostscript
$ ! General Public License.  A copy of this license is supposed to have been
$ ! given to you along with Ghostscript so you can know your rights and
$ ! responsibilities.  It should be in a file named COPYING.  Among other
$ ! things, the copyright notice and this notice must be preserved on all
$ ! copies.
$ !
$ !
$ ! "makefile" for Ghostscript, VMS / VMS C / DECwindows (X11) configuration.
$ !
$ !
$ ! Execute this command file while in the GhostScript directory!
$ !
$ !
$ ! P1 may be used to specify a DEBUG flag:
$ !
$ !          $ @VMS-CC.MAK DEBUG
$ !
$ !
$ CDEF = ""
$ LDEF = ""
$ GS_LIB_DEFAULT = F$ENVIRONMENT("DEFAULT")
$ !
$ IF P1 .NES. "DEBUG" THEN GOTO NODEFS
$ CDEF = "/DEFINE=(""DEBUG"")/NOOPTIMIZE/DEBUG"
$ LDEF = "/DEBUG"
$ !
$ NODEFS:
$ !
$ ! Give ourself a healthy search list for C include files
$ !
$ DEFINE C$INCLUDE 'F$ENVIRONMENT("DEFAULT"),DECW$INCLUDE,SYS$LIBRARY
$ DEFINE VAXC$INCLUDE C$INCLUDE
$ DEFINE SYS SYS$LIBRARY
$ !
$ !
$ ! Build the ANSI C to Kernighan & Ritchie filter
$ !
$ CC/NOLIST/OBJECT=ANSI2KNR.OBJ ANSI2KNR.C
$ LINK/NOMAP/EXE=ANSI2KNR.EXE ANSI2KNR,SYS$INPUT/OPT
SYS$SHARE:DECW$XLIBSHR/SHARE
$ DELETE ANSI2KNR.OBJ.*
$ !
$ ! Now define an ansi2knr symbol
$ !
$ ANSI2KNR = "$" + F$ENVIRONMENT("DEFAULT") + "ANSI2KNR.EXE"
$ !
$ !
$ ! Compile genarch.c and then run it to create the arch.h header file
$ !
$ CC/NOLIST/OBJECT=GENARCH.OBJ GENARCH.C
$ LINK/NOMAP/EXE=GENARCH.EXE GENARCH,SYS$INPUT/OPT
SYS$SHARE:VAXCRTL/SHARE
$ RUN GENARCH.EXE
$ DELETE GENARCH.EXE.*,GENARCH.OBJ.*
$ PURGE ARCH.H
$ !
$ !
$ ! Create an empty object library
$ !
$ LIBRARY/CREATE GS.OLB
$ !
$ !
$ ! Create a list of modules to compile and store in the object library
$ !
$ CREATE MODULES.LIS
GDEVMEM
GP_VMS
GSCHAR
GSCOLOR
GSCOORD
GSDEVICE
GSFILE
GSFONT
GSIM2OUT
GSIMAGE
GSLINE
GSMATRIX
GSMISC
GSPAINT
GSPATH
GSPATH2
GSSTATE
GSTYPE1
GVIRTMEM
GXCACHE
GXCOLOR
GXDITHER
GXDRAW
GXFILL
GXHT
GXPATH
GXPATH2
GXSTROKE
IALLOC
IDEBUG
IDICT
IINIT
INAME
INTERP
ISCAN
IUTIL
STREAM
ZARITH
ZARRAY
ZCHAR
ZCOLOR
ZCONTROL
ZDEVICE
ZDICT
ZFILE
ZFONT
ZGENERIC
ZGSTATE
ZHT
ZMATH
ZMATRIX
ZMISC
ZPAINT
ZPATH
ZPATH2
ZRELBIT
ZSTACK
ZSTRING
ZTYPE
ZVMEM
$ !
$ !
$ ! NOW COMPILE AWAY!
$ !
$ OPEN/READ MODULE_LIST MODULES.LIS
$ !
$ COMPILE_LOOP:
$ READ/END=END_COMPILE MODULE_LIST MODULE
$ ANSI2KNR 'MODULE'.C 'MODULE'.CC
$ CC'CDEF/NOLIST/OBJECT='MODULE'.OBJ 'MODULE'.CC
$ LIBRARY/INSERT GS.OLB 'MODULE'.OBJ
$ DELETE 'MODULE'.OBJ.*
$ IF CDEF .EQS. "" THEN DELETE 'MODULE'.CC.*
$ GOTO COMPILE_LOOP
$ !
$ END_COMPILE:
$ DELETE MODULES.LIS.*
$ !
$ !
$ ! Is the DECwindows environment about?  Must be installed in order to
$ ! build the executable programs gs.exe, gt.exe, and xlib.exe.
$ !
$ IF F$SEARCH("SYS$SHARE:DECW$XLIBSHR.EXE") .NES. "" THEN GOTO CHECK2
$ WRITE SYS$OUTPUT "DECwindows user environment not installed;"
$ WRITE SYS$OUTPUT "unable to build executable programs."
$ GOTO DONE
$ !
$ CHECK2:
$ IF F$TRNLNM("DECW$INCLUDE") .NES. "" THEN GOTO BUILD_EXES
$ WRITE SYS$OUTPUT "You must invoke @DECW$STARTUP before using this"
$ WRITE SYS$OUTPUT "command procedure to build the executable programs."
$ GOTO DONE
$ !
$ ! Build the executables
$ !
$ BUILD_EXES:
$ !
$ DEFINE X11 DECW$INCLUDE
$ !
$ !
$ CREATE GDEVS.H
d(gs_x11_device)
$ !
$ ANSI2KNR GDEVS.C GDEVS.CC
$ CC'CDEF/NOLIST/OBJECT=GDEVS.OBJ GDEVS.CC
$ !
$ ANSI2KNR GDEVX.C GDEVX.CC
$ CC'CDEF/NOLIST/OBJECT=GDEVX.OBJ GDEVX.CC
$ !
$ ANSI2KNR GSMAIN.C GSMAIN.CC
$ CC'CDEF/NOLIST/OBJECT=GSMAIN.OBJ GSMAIN.CC
$ !
$ ANSI2KNR UTRACE.C UTRACE.CC
$ CC'CDEF/NOLIST/OBJECT=UTRACE.OBJ UTRACE.CC
$ !
$ !
$ ! GSMAIN and UTRACE are tossed into the GT link so that when a
$ ! debugging configuration is built, the gs_log_error and gs_exit
$ ! routines will be defined.
$ !
$ ANSI2KNR GT.C GT.CC
$ CC'CDEF/NOLIST/OBJECT=GT.OBJ GT.CC
$ LINK'LDEF/NOMAP/EXE=GT.EXE GT,GSMAIN,UTRACE,GDEVX,GDEVS,-
  GS/LIB/INCLUDE=GDEVMEM,SYS$INPUT/OPT
SYS$SHARE:DECW$XLIBSHR/SHARE
$ !
$ ANSI2KNR GS.C GS.CC
$ LIBDEF = """GS_LIB_DEFAULT=""""" + ''GS_LIB_DEFAULT' + """"""""
$ CC'CDEF/NOLIST/DEFINE=('LIBDEF')/OBJECT=GS.OBJ GS.CC
$ LINK'LDEF/NOMAP/EXE=GS.EXE GS,GSMAIN,UTRACE,GDEVX,GDEVS,-
 GS/LIB/INCLUDE=GDEVMEM,SYS$INPUT/OPT
SYS$SHARE:DECW$XLIBSHR/SHARE
$ !
$ DELETE GDEVX.OBJ.*,GSMAIN.OBJ.*,UTRACE.OBJ.*,GT.OBJ.*,GS.OBJ.*,GDEVS.OBJ.*
$ IF CDEF .EQS. "" THEN -
 DELETE GDEVX.CC.*,GSMAIN.CC.*,UTRACE.CC.*,GT.CC.*,GS.CC.*,GDEVS.CC.*
$ !
$ DELETE ANSI2KNR.EXE.*
$ !
$ DEASSIGN X11
$ !
$ DONE:
$ !
$ DEASSIGN C$INCLUDE
$ DEASSIGN VAXC$INCLUDE
$ DEASSIGN SYS
$ !
$ ! ALL DONE